Aċċess għad-dejta miftuħa tal-Unjoni Ewropea
EUROPAPortal tad-Dejta Miftuħa tal-UE SPARQL
Menu
Ħarsa ġenerali Għodod Riżorsi edukattivi Proġetti Sandbox

KIF TUŻA L-SPARQL Endpoint

Biex ikollok aċċess għall-Portal tad-Dejta Miftuħa tal-UE għad-dejta maħżuna bħala tripla, SPARQL endpoint li jinqara mill-kompjuter jippermetti mistoqsijiet dwar id-deskrizzjonijiet ta’ settijiet ta’ dejta RDF.

SPARQL hija lingwa tat-tiftix RDF jiġifieri lingwa għat-tiftix semantiku tal-lingwa għall-bażijiet tad-dejta.

Il-paġna tad-dejta llinkjata tal-portal toffri interfaċċja grafika tal-utent fejn iddaħħal il-mistoqsijiet SPARQL tiegħek.

Għal użu programmatiku, endpoint li jinqara mill-kompjuter huwa disponibbli hawn: http://data.europa.eu/euodp/sparqlep

It-Taqsima li ġejja tipprovdi introduzzjoni qasira għall-lingwa tal-SPARQL flimkien ma' xi eżempji speċifiċi fil-kuntest tal-Portal tad-Dejta Miftuħa tal-UE.

Għal dokumentazzjoni sħiħa tal-lingwa, l-ispeċifikazzjonijiet tal-SPARQL jinstabu fuq is-sit web W3C. Il-mudelli użati biex jispjegaw is-settijiet ta’ dejta katalogati fil-Portal tad-Dejta Miftuħa tal-UE huma deskritti fil-paġna dwar ‘Dejta Llinkjata’, fil-kapitlu ‘Il-vokabolarju tal-metadejta’.

PREFIX

Bħala taqsira, biex jiġi evitat li joqogħdu jinkitbu l-URIs sħaħ fil-mistoqsijiet, jistgħu jiġu definiti prefissi f’tiftixa.

Is-sintassi li għandha tintuża hija din li ġejja:

PREFIX ${PREFIX_NAME}: ${FULL_URI}

Fejn:

  • ${PREFIX_NAME} huwa l-isem tat-taqsira li se tintużaw fit-talba minflok il-verżjoni sħiħa tal-URI.
  • ${FULL_URI} hu l-URI li se jiġi sostitwit bil-prefiss.

Eżempju 1: jiġbor il-lista ta’ pubblikaturi tas-settijiet tad-dejta ordnati mill-URIs tal-pubblikaturi:

PREFIX dcat: <http://www.w3.org/ns/dcat#>

PREFIX dc: <http://purl.org/dc/terms/>

SELECT distinct ?Publisher WHERE {

?DatasetURI a dcat:Dataset .

?DatasetURI dc:publisher ?Publisher

 }

ORDER BY (?Publisher) LIMIT 100

SELECT

Il-keyword SELECT tintuża biex tindika li biċċa informazzjoni (varjabbli) għandha tiġi ritornata mill-mistoqsija. Is-sintassi “SELECT *” hija abbrevjazzjoni li tagħżel il-varjabbli kollha ta’ mistoqsija.

Huwa possibbli tagħżel varjabbli multipli.

Eżempju 2: jiġbor id-data tal-ħruġ u l-istatus speċifiku ta’ settijiet ta’ dejta:

PREFIX odp: <http://data.europa.eu/euodp/ontologies/ec-odp#>

PREFIX dc: <http://purl.org/dc/terms/>

SELECT ?issued ?status WHERE {

<https://ec.europa.eu/esco> dc:issued ?issued .

<https://ec.europa.eu/esco> odp:datasetStatus ?status

}

Il-keyword DISTINCT tintużaw biex tiggarantixxi l-uniċità tar-riżultati.

Eżempju 3: jiġbor lista ta’ pubblikaturi ta’ settijiet ta’ dejta (mingħajr duplikati):

PREFIX dcat: <http://www.w3.org/ns/dcat#>

PREFIX dc: <http://purl.org/dc/terms/>

SELECT DISTINCT ?Publisher

WHERE {

?DatasetURI a dcat:Dataset .

?DatasetURI dc:publisher ?Publisher

}

ORDER BY (?Publisher)

Fl-eżempju ta’ hawn fuq, intużat it-taqsira "a". Hija tieħu post il-proprjetà ta' “rdf:type”.

Il-keyword COUNT tintuża biex issib in-numru ta’ riżultati ta’ varjabbli.

Eżempju 4: jiġbor l-għadd ta’ settijiet ta’ dejta minn pubblikatur imqassmin skont in-numru ta’ sett (f’ordni mill-kbir għaż-żgħir).

PREFIX dc: <http://purl.org/dc/terms/>

PREFIX dcat: <http://www.w3.org/ns/dcat#>

SELECT ?Publisher COUNT(?DatasetURI) AS ?DatasetNumber

WHERE {

?DatasetURI a dcat:Dataset .

?DatasetURI dc:publisher ?Publisher

} ORDER BY desc (?DatasetNumber)

WHERE

Il-keyword WHERE tintuża biex tispeċifika lista ta’ mudelli li jillimitaw l-informazzjoni li tinkiseb. Dawn il-mudelli huma tripli fejn xi elementi jistgħu jiġu sostitwiti b’varjabbli.

Sabiex jinfirdu għadd ta’ xejriet jintuża l-karattru “.” bħala separatur. Dan jippermetti li jiġu kkombinati l-mudelli. Il-kombinazzjoni tagħhom taħdem bħall-operatur loġiku AND.

Eżempju 5: Agħżel il-pubblikaturi li ppubblikaw xi settijiet tad-dejta tat-tip “NameAuthorityList” u l-għadd ta’ settijiet ta’ dejta:

PREFIX dc: http://purl.org/dc/terms/

PREFIX dcat: <http://www.w3.org/ns/dcat#>

PREFIX odp: <http://data.europa.eu/euodp/ontologies/ec-odp#>

SELECT distinct ?Publisher count(?DatasetURI )

WHERE {

?DatasetURI a dcat:Dataset .

?DatasetURI dc:publisher ?Publisher .

?DatasetURI odp:datasetType <http://data.europa.eu/euodp/kos/dataset-type/NameAuthorityList>

}

LIMIT

Il-keyword LIMIT tippermetti limitu fuq in-numru ta’ riżultati li jiġu rritornati.

Ara l-Eżempju 1.

OPTIONAL

Bil-keyword OPTIONAL xi mudelli fil-klawżola WHERE jistgħu jiġu ssettjati bħala mhux obbligatorji.

Eżempju 6: Jiġbor is-settijiet kollha tad-dejta li jkollhom riżorsa b’format “text/csv” u, jekk disponibbli, jiġbor id-data tal-bidu tal-perjodu tal-kopertura temporali ta’ settijiet ta’ dejta differenti.

PREFIX dc: http://purl.org/dc/terms/

PREFIX dcat: <http://www.w3.org/ns/dcat#>

PREFIX odp: <http://data.europa.eu/euodp/ontologies/ec-odp#>

SELECT ?DatasetURI ?period_start WHERE {

?DatasetURI a dcat:Dataset .

?DatasetURI dcat:distribution ?o .

?o odp:distributionFormat "text/csv" .

OPTIONAL {

?DatasetURI dc:temporal ?period .

?period odp:periodStart ?period_start

 }

}

 

FROM

Fil-ħażna tripla (li taħżen l-informazzjoni RDF), it-tripli jistgħu jiġu raggruppati skont il-grafika. Imbagħad, minn talba, huwa possibbli li t-tiftixa tiġi limitata għal grafika speċifika. Fil-kuntest tal-Portal tad-Dejta Miftuħa tal-UE, kull rekord ta' katalgu tinħażen fil-grafika tagħha stess.

Eżempju 7: Jiġbor it-tripli kollha ta’ rekord ta' katalogu speċifiku:

SELECT * FROM <http://data.europa.eu/euodp/data/dataset/PY7AnlFr46ANQZvz1nAhcg>

WHERE {

 ?s ?p ?o

}

FILTER

Il-keyword FILTER tipprovdi restrizzjoni ulterjuri għas-soluzzjonijiet ta’ propożizzjoni WHERE. Ir-restrizzjonijiet jistgħu jkunu għal regex għal mudelli jew l-għażla tal-lingwa.

Eżempju 8: Agħżel is-settijiet kollha tad-dejta li għandhom titlu bit-Taljan

PREFIX dcat: <http://www.w3.org/ns/dcat#>

PREFIX dc: <http://purl.org/dc/terms/>

SELECT ?DatasetURI ?title WHERE {

?DatasetURI a dcat:Dataset .

?DatasetURI dc:title ?title

FILTER (lang(?title)='it')

}

Eżempju 9: Iġbor is-settijiet kollha tad-dejta li jkollhom il-kelma prinċipali “annimal” fit-titolu tagħhom bl-Ingliż

PREFIX dcat: <http://www.w3.org/ns/dcat#>

PREFIX dc: <http://purl.org/dc/terms/>

SELECT ?DatasetURI ?title WHERE {

?DatasetURI a dcat:Dataset .

?DatasetURI dc:title ?title

FILTER (lang(?title)='en')

FILTER(regex(?title, "animal", "i"))

}

Il-parametru fakultattiv i fil-funzjoni regex jippermetti riżultati b’każijiet differenti (mhux sensittiv għat-tipa).

Uża Każ  – jiġbor il-metadejta kollha tar-rekords kollha.

Peress li l-fornituri tad-dejta jistgħu jipprovdu metadejta addizzjonali meta mqabbla mal-mudell CKAN, l-aħjar metodu jkun li jintuża l-SPARQL endpoint għal din il-mistoqsija.

SELECT  * WHERE {

GRAPH ?graph {

?s ?p ?o

}

FILTER (regex(?graph, "^http://data.europa.eu/euodp/data/dataset/"

))}

Din il-mistoqsija se turi parti biss mill-katalgu minħabba li l-ħażna tripla għandha limitu fuq it-tripli li tista' turi. Biex tevita dan il-limitu, il-metodu rakkomandat huwa l-użu ta’ paġinazzjoni permezz  tal-keywords LIMIT u OFFSET.